Pascal 入門

program hello(output);
begin
  writeln('hello, world')   { 文字列を出力 }
end.

program プログラム名(ファイル名1, ファイル名2, ...);

program sample(output);
var
  n : integer;
  p : real;
begin
  n := 5;
  p := n;
  writeln(n);
  writeln(p)
end.

var
  変数名1, 変数名2, ... : 型名;
  ...

program sample(output);
const
  pi = 3.14;
var
  r, area : real;
begin
  r := 2.0;
  area := pi * r * r;  { 12.56 }
end.

program sample(output);
var
  n : 0..maxint;
  d : '0'..'9';
begin
  n := 0;    { 可 }
  n := -1;   { 不可 }
  d := '5';  { 可 }
  d := 'a'   { 不可 }
end.

program sample(output);
type
  natural = 0..maxint;
  digit = '0'..'9';
var
  n : natural;
  d : digit;
begin
  ...
end.

program sample(output);
type
  dayofweek = (mon, tue, wed, thu, fri, sat, sun);
var
  d : dayofweek;
begin
  d := tue
end.

program sample(output);
var
  s : string(256);
begin
  s := 'hello';
  writeln(s)
end.

program sample(output);
var
  arr : array [1..3] of char;
begin
  arr[1] := 'a';
  arr[2] := 'b';
  arr[3] := 'c';
end.

program sample(output);
type
  dayofweek = (mon, tue, wed, thu, fri, sat, sun);
var
  arr : array [dayofweek] of integer;
begin
  arr[tue] := 256;
end.

program sample(output);
var
  arr : array [1..2] of array [1..3] of char;
begin
  arr[1][1] := 'a';
  arr[1][2] := 'b';
  arr[1][3] := 'c';
  arr[2][1] := 'A';
  arr[2][2] := 'B';
  arr[2][3] := 'C';
end.

program sample(output);
var
  arr : array [1..2, 1..3] of char;
begin
  arr[1, 1] := 'a';
  ...
end.

type
  charray = packed array [1..100] of char;

program sample(output);
var
  a, b : integer;
begin
  a := 2;
  b := 3;
  write('a + b = ', a + b);  { 複数引数を指定可能 }
  writeln                    { 改行のみを行う }
end.

program sample(output);
begin
  writeln(3:8);                   { 値:幅 }
  writeln(3.14159265358979:8:2);  { 値:幅:精度 }
end.

program sample(input, output);
var
  a, b : integer;
begin
  readln(a, b);
  writeln('a + b = ', a + b)
end.

1 + 2 * 3     { 7 }
(1 + 2) * 3   { 9 }

10 / 3       { 3.333... }
10 div 3     { 3 }

if 条件式 then 文
if 条件式 then 文 else 文

program sample(output);
var
  a, b : integer;
begin
  a := 2; b := 3;
  if a = b then writeln('a = b')
  else if a > b then writeln('a > b')
  else writeln('a < b')
end.

if a > b then
begin
  tmp := a;
  a := b;
  b := tmp
end

case 選択式 of
  ラベル1: 文1;
  ...
end

program sample(output);
var
  month, days : integer;
begin
  month := 7;
  case month of
    1, 3, 5, 7, 8, 10, 12: days := 31;
    2: days := 28;
    4, 6, 9, 11: days := 30;
  end;
  writeln(days)
end.

for 変数 := 始値 to 終値 do 文
for 変数 := 始値 downto 終値 do 文

program sample(output);
var
  i : integer;
begin
  for i := 1 to 5 do writeln(i)
end.

for i := -1 downto -5 do writeln(i)

while 条件式 do 文

i := 1;
while i <= 5 do begin
  writeln(i);
  i := i + 1
end

repeat 文 until 条件式

i := 1;
repeat
  writeln(i);
  i := i + 1
until i > 5

program sample(output);
label
  100;
var
  i : integer;
begin
  i := 1;
100:
  writeln(i);
  i := i + 1;
  if i <= 5 then goto 100
end.

label
  ラベル1, ラベル2, ...;

program sample(output);

{ 文字 c を n 個出力する手続き }
procedure nchars(c : char; n : integer);
var
  i : integer;
begin
  for i := 1 to n do write(c)
end;

begin
  nchars('*', 7);
  writeln
end.

procedure 手続き名(仮引数の宣言);
ローカルな定義や宣言
begin
  処理
end;

program sample(output);

{ 整数 m, n の最大公約数を求める関数 }
function gcd(m, n : integer) : integer;
var
  r : integer;
begin
  while n <> 0 do
  begin
    r := m mod n;
    m := n;
    n := r
  end;
  gcd := m
end;

begin
  writeln(gcd(84, 35))  { 出力: 7 }
end.

function 関数名(仮引数の宣言) : 返却型;
ローカルな定義や宣言
begin
  処理
end;

procedure swap(var m, n : integer);
var
  t : integer;
begin
  t := m; m := n; n := t
end;

program sample(output);
var
  arr : array [1..3] of char;

{ 文字配列 a の各要素を出力する手続き }
procedure printelem(
  a : array [low..high : integer] of char);  { 整合配列 }
var
  i : integer;
begin
  for i := low to high do writeln(a[i])
end;

begin
  arr[1] := 'a';
  arr[2] := 'b';
  arr[3] := 'c';
  printelem(arr)
end.

type charray = array [1..10] of char;

procedure hoge(a : charray);                { 可 }
procedure piyo(a : array [1..10] of char);  { 不可 }

program sample(output);
var
  arr : array [1..5] of char;

{ x < y であれば true を返す }
function less(x, y : char) : boolean;
begin
  less := x < y
end;

{ 文字変数 a, b の値を交換する }
procedure swap(var a, b : char);
var
  t : char;
begin
  t := a; a := b; b := t
end;

{ 関数 f に基づいてソートを行う }
procedure sort(
  var a : array [low..high : integer] of char;
  function f(x, y : char) : boolean);   { 関数引数 }
var
  i, j : integer;
begin
  for i := high downto low + 1 do
    for j := low to i - 1 do
      if not f(a[j], a[j + 1]) then swap(a[j], a[j + 1])
end;

begin
  arr[1] := 'd';  arr[2] := 'a';  arr[3] := 'e';
  arr[4] := 'b';  arr[5] := 'c';
  sort(arr, less);
  writeln(arr)   { 出力: abcde }
end.

program sample(output);
var
  a, b : set of 1..10;

begin
  a := [ 1, 3, 5..8 ];  { a の要素は 1, 3, 5, 6, 7, 8 }
  b := [ 1, 3, 6, 8 ];  { b の要素は 1, 3, 6, 8 }

  writeln(a = b);    { false }
  writeln(a > b);    { true }
  writeln(5 in a);   { true }
  writeln(5 in b);   { false }
end.

program sample(output);
type
  person = record
      name : string(256);
      age : integer
    end;
var
  p : person;
begin
  p.name := 'Nagao';
  p.age := 20;
  writeln(p.name);
  writeln(p.age)
end.

program sample(output);
type
  person = record
      name : string(256);
      age : integer
    end;
var
  p : person;
begin
  with p do  { with 文中では p. を省略できる }
  begin
    name := 'Nagao';
    age := 20;
    writeln(name);
    writeln(age)
  end
end.

program sample(output);
type
  shape = record
      case flag : (circ, rect) of
        circ : (radius : real);
        rect : (width, height : real);
    end;
var
  s : shape;
begin
  s.flag := circ;
  s.radius := 2.0;
  
  writeln(s.radius:0:2);  { 2.00 }
  
  writeln(s.width:0:2);   { 2.00 }
  writeln(s.height:0:2);  { 意味のない値 }
end.

case タグフィールド : タグ型 of
  定数 : (フィールドの宣言);
  ...

program sample(output);
var
  p, q : ^integer;
begin
  new(p);       { 動的に領域を確保 }
  q := p;       { p, q は同じ領域を指す }
  p^ := 5;
  writeln(p^);  { 5 }
  writeln(q^);  { 5 }
  dispose(p);   { 領域を解放 }
end.

ptr := nil

program sample(f, output);
var
  f : text;
  buf : string(256);
begin
  assign(f, 'hoge.txt');
  reset(f);      { ファイルを読み込み用に開く }
  while not eof(f) do
  begin
    readln(f, buf);
    writeln(buf)
  end;
  close(f)
end.

program sample(f);
var
  f : text;
begin
  assign(f, 'hoge.txt');
  rewrite(f);      { ファイルを書き込み用に開く }
  writeln(f, 'This is some sample text.');
  close(f)
end.

program sample(f);
var
  f : file of real;
  i : integer;
begin
  assign(f, 'hoge.dat');
  rewrite(f);
  for i := 1 to 5 do
  begin
    f^ := 1 / i;
    put(f);
  end;
  close(f)
end.

program sample(f, output);
var
  f : file of real;
  n : real;
begin
  assign(f, 'hoge.dat');
  reset(f);
  while not eof(f) do
  begin
    n := f^;
    writeln(n:0:2);
    get(f);
  end;
  close(f)
end.